Feature-Request: Lablels in Columns

An area of the forum to post ideas for new products or discuss things that are not related to 2BrightSparks products
DennisK
Advanced
Advanced
Posts: 48
Joined: Sun Apr 28, 2013 2:05 pm

Feature-Request: Lablels in Columns

Postby DennisK » Sun May 15, 2016 9:14 am

Hi there!

In the "Profile Settings Window" you can set individual Names for "Source" and "Destination", for example "Mom's PC" and "Family NAS".

Wouldn't it be great so see these labels as optional columns in the "Main Window"? Sometimes it's easier so see the machines name than the path. :-)

Thx!

Dennis

User avatar
mickyj
2BrightSparks Staff
2BrightSparks Staff
Posts: 906
Joined: Mon Jan 05, 2004 6:51 pm

Re: Feature-Request: Lablels in Columns

Postby mickyj » Tue May 17, 2016 3:42 am

Hi,

If you're using SyncBackPro you can use a simple script to do this:

Code: Select all

'
' Example script for 2BrightSparks SyncBackPro that adds two extra
' columns in the main window that shows the location labels.
'
' You need to install this script and enable it on the Main Interface
' tab.
'
' SBLang=VBScript
'
' http://www.2BrightSparks.com/
'

'
' This is a main interface script
'
Function Description(ByRef ScriptType)
  Description = "Show the location labels"
  ScriptType = 4
End Function

Function MainColumnsCount()
  MainColumnsCount = 2
End Function

'
' Column title. Ignore Width and just use the default.
'
Function MainColumnTitle(Col, ByRef Width)
  If Col = 0 Then
    MainColumnTitle = "Source/Left"
  Else
    MainColumnTitle = "Destination/Right"
  End if
End Function

'
' Column text. If its a group then we have no info.
'
Function MainColumnText(Col, IsGroup, ProfileName)
  ' Ignore groups
  If Not IsGroup Then
    If Col = 0 Then
      MainColumnText = SBVariables.GetProfileProperty(ProfileName, "SrcLabel", "Source", True)
    Else
      MainColumnText = SBVariables.GetProfileProperty(ProfileName, "DestLabel", "Destination", True)
    End if
  Else
    MainColumnText = ""
  End If
End Function


Create a text file and paste the above code into it, save it and rename it so it has a .VBS extension instead of .TXT then install the script into SyncBackPro (via Preferences->Scripts in the main menu). Once the script is installed and enabled you'll need to exit SyncBackPro and start it again.

DennisK
Advanced
Advanced
Posts: 48
Joined: Sun Apr 28, 2013 2:05 pm

Re: Feature-Request: Lablels in Columns

Postby DennisK » Sun Sep 11, 2016 11:05 am

Thank you, I'll try it.


Return to “Ideas and general discussion”



Who is online

Users browsing this forum: No registered users and 1 guest